mirror of
https://github.com/NVIDIA/nvbench.git
synced 2026-03-14 20:27:24 +00:00
a2f88ff790
* Set `CUDA_MODULE_LOADING=EAGER` before `main`. Fixes #136 * Portability for `setenv`. * Remove pre-main CUDART usage and setup env in main. * Fail examples if they deadlock. This is the best way we have to diagnose a regression for NVIDIA/nvbench#136. * Add an initialize method to benchmark_manager for CUDA-related setup. Benchmarks are created statically, so their constructors cannot call the CUDA APIs without breaking the CUDA_MODULE_LOAD setup. This method is called from `main` after the environment has been configured.
61 lines
1.9 KiB
CMake
61 lines
1.9 KiB
CMake
set(example_srcs
|
|
auto_throughput.cu
|
|
axes.cu
|
|
custom_criterion.cu
|
|
enums.cu
|
|
exec_tag_sync.cu
|
|
exec_tag_timer.cu
|
|
skip.cu
|
|
stream.cu
|
|
throughput.cu
|
|
)
|
|
|
|
# Metatarget for all examples:
|
|
add_custom_target(nvbench.example.all)
|
|
add_dependencies(nvbench.all nvbench.example.all)
|
|
|
|
foreach(example_src IN LISTS example_srcs)
|
|
get_filename_component(example_name "${example_src}" NAME_WLE)
|
|
string(PREPEND example_name "nvbench.example.")
|
|
add_executable(${example_name} "${example_src}")
|
|
nvbench_config_target(${example_name})
|
|
target_include_directories(${example_name} PRIVATE "${CMAKE_CURRENT_LIST_DIR}")
|
|
target_link_libraries(${example_name} PRIVATE nvbench::main)
|
|
set_target_properties(${example_name} PROPERTIES COMPILE_FEATURES cuda_std_17)
|
|
add_test(NAME ${example_name}
|
|
COMMAND "$<TARGET_FILE:${example_name}>" --timeout 0.1 --min-time 1e-5
|
|
)
|
|
|
|
# These should not deadlock. If they do, it may be that the CUDA context was created before
|
|
# setting CUDA_MODULE_LOAD=EAGER in main, see NVIDIA/nvbench#136.
|
|
set_tests_properties(${example_name} PROPERTIES
|
|
FAIL_REGULAR_EXPRESSION "Possible Deadlock Detected"
|
|
)
|
|
|
|
add_dependencies(nvbench.example.all ${example_name})
|
|
endforeach()
|
|
|
|
# Silence some warnings from old thrust headers:
|
|
set(thrust_examples
|
|
auto_throughput
|
|
axes
|
|
custom_criterion
|
|
exec_tag_sync
|
|
exec_tag_timer
|
|
skip
|
|
stream
|
|
throughput
|
|
)
|
|
foreach (example IN LISTS thrust_examples)
|
|
if (CMAKE_CXX_COMPILER_ID STREQUAL "MSVC")
|
|
# C4324: structure was padded due to alignment specifier
|
|
nvbench_add_cxx_flag(nvbench.example.${example} PRIVATE "/wd4324")
|
|
|
|
# warning C4201: nonstandard extension used: nameless struct/union:
|
|
# Fixed in Thrust 1.12.0 (CTK 11.4, NV HPC 21.3)
|
|
if (${CUDAToolkit_VERSION} VERSION_LESS 11.4)
|
|
nvbench_add_cxx_flag(nvbench.example.${example} PRIVATE "/wd4201")
|
|
endif()
|
|
endif()
|
|
endforeach()
|