# Copyright (c) Advanced Micro Devices, Inc., or its affiliates.
# SPDX-License-Identifier: MIT

include_directories(BEFORE
    ${PROJECT_SOURCE_DIR}/include
    ${PROJECT_SOURCE_DIR}/library/include
)

if(WIN32)
    # On Windows, HIP uses -nostdlib which prevents C runtime linking
    # We need legacy_stdio_definitions.lib to provide vfprintf and other legacy C functions
    # This is mainly needed for the getopt library.
    set(LEGACY_STDIO_SEARCH_PATHS)
    
    # Try to use Visual C++ Tools environment variable (if build executes from Visual Studio Developer Command Prompt)
    if(DEFINED ENV{VCToolsInstallDir})
        list(APPEND LEGACY_STDIO_SEARCH_PATHS "$ENV{VCToolsInstallDir}/lib/x64")
    endif()
    
    # Fallback: Search common Visual Studio installation locations
    file(GLOB MSVC_LIB_PATHS "C:/Program Files/Microsoft Visual Studio/*/*/VC/Tools/MSVC/*/lib/x64")
    list(APPEND LEGACY_STDIO_SEARCH_PATHS ${MSVC_LIB_PATHS})
    
    # Use find_library to locate the library
    find_library(LEGACY_STDIO_LIB legacy_stdio_definitions 
        PATHS ${LEGACY_STDIO_SEARCH_PATHS} 
        NO_DEFAULT_PATH
    )
    
    if(LEGACY_STDIO_LIB)
        message(STATUS "Found legacy_stdio_definitions.lib: ${LEGACY_STDIO_LIB}")
        add_link_options("SHELL:-Xlinker \"${LEGACY_STDIO_LIB}\"")
    else()
        message(WARNING "Could not find legacy_stdio_definitions.lib - examples may fail to link.")
    endif()
endif()

add_custom_target(examples)


# list of examples that are labelled as REGRESSION_EXAMPLE for make regression (runtime more than 30 seconds)
# all other tests are labelled as SMOKE_EXAMPLE
set(REGRESSION_EXAMPLES
    example_sparse_embedding3_forward_layernorm
)


function(add_example_dependencies EXAMPLE_NAME FILE_NAME)
    if(FILE_NAME)
        add_dependencies(EXAMPLE_NAME FILE_NAME)
    endif()
endfunction(add_example_dependencies EXAMPLE_NAME)

function(add_example_executable EXAMPLE_NAME FILE_NAME)
    message(DEBUG "adding example ${EXAMPLE_NAME}")
    set(result 1)
    if(DEFINED DTYPES)
        foreach(source IN LISTS FILE_NAME)
            get_filename_component(source_name ${source} NAME)
            set(test 0)
            if((source_name MATCHES "_fp16" OR source_name MATCHES "_f16") AND NOT "fp16" IN_LIST DTYPES)
                set(test 1)
            endif()
            if((source_name MATCHES "_fp32" OR source_name MATCHES "_f32") AND NOT "fp32" IN_LIST DTYPES)
                set(test 1)
            endif()
            if((source_name MATCHES "_fp64" OR source_name MATCHES "_f64") AND NOT "fp64" IN_LIST DTYPES)
                set(test 1)
            endif()
            if((source_name MATCHES "_fp8" OR source_name MATCHES "_f8") AND NOT "fp8" IN_LIST DTYPES)
                set(test 1)
            endif()
            if((source_name MATCHES "_bf8" OR source_name MATCHES "_bf8") AND NOT "bf8" IN_LIST DTYPES)
                set(test 1)
            endif()
            if((source_name MATCHES "_bf16" OR source_name MATCHES "_b16") AND NOT "bf16" IN_LIST DTYPES)
                set(test 1)
            endif()
            if((source_name MATCHES "_int8" OR source_name MATCHES "_i8") AND NOT "int8" IN_LIST DTYPES)
                set(test 1)
            endif()
            if(test EQUAL 1)
                message(DEBUG "removing example source file ${source} ")
                list(REMOVE_ITEM FILE_NAME "${source}")
            endif()
        endforeach()
    endif()

    set(EX_TARGETS ${SUPPORTED_GPU_TARGETS})

    foreach(source IN LISTS FILE_NAME)
        get_filename_component(source_name ${source} NAME)
        #Do not build any DL examples if DL_KERNELS not set
        if(NOT DEFINED DL_KERNELS AND source_name MATCHES "_dl")
            message(DEBUG "removing dl example ${source} ")
            list(REMOVE_ITEM FILE_NAME "${source}")
        endif()
        #Do not build any DPP examples if DPP_KERNELS not set
        if(NOT DEFINED DPP_KERNELS AND source_name MATCHES "_dpp")
            message(DEBUG "removing dpp example ${source} ")
            list(REMOVE_ITEM FILE_NAME "${source}")
        endif()
        #Do not build any XDL examples if gfx9 targets are not on the list
        if(NOT EX_TARGETS MATCHES "gfx9" AND NOT EX_TARGETS MATCHES "gfx11" AND NOT EX_TARGETS MATCHES "gfx12" AND source_name MATCHES "_xdl")
            message(DEBUG "removing xdl example ${source} ")
            list(REMOVE_ITEM FILE_NAME "${source}")
        endif()
        #Do not build any WMMA examples if gfx11 targets are not on the list
        if(NOT EX_TARGETS MATCHES "gfx11" AND NOT EX_TARGETS MATCHES "gfx12" AND source_name MATCHES "_wmma")
            message(DEBUG "removing wmma example ${source} ")
            list(REMOVE_ITEM FILE_NAME "${source}")
        endif()
        #Do not build any microscaling examples if gfx950 target is not on the list
        if(NOT EX_TARGETS MATCHES "gfx950" AND source_name MATCHES "_mx")
            message(DEBUG "removing microscaling example ${source} ")
            list(REMOVE_ITEM FILE_NAME "${source}")
        endif()
        #Do not build any FP8 examples if CK_ENABLE_FP8 not set
        if(NOT DEFINED CK_ENABLE_FP8 AND source_name MATCHES "_fp8")
            message(DEBUG "removing fp8 example ${source} ")
            list(REMOVE_ITEM FILE_NAME "${source}")
        endif()
        #Do not build any BF8 examples if CK_ENABLE_BF8 not set
        if(NOT DEFINED CK_ENABLE_BF8 AND source_name MATCHES "_bf8")
            message(DEBUG "removing bf8 example ${source} ")
            list(REMOVE_ITEM FILE_NAME "${source}")
        endif()
        # Build fp8 gemm_multiply_multiply and moe only on gfx94/95 and gfx12
        if(NOT EX_TARGETS MATCHES "gfx94" AND NOT EX_TARGETS MATCHES "gfx95" AND NOT EX_TARGETS MATCHES "gfx12")
            if(source_name MATCHES "fp8" AND source_name MATCHES "(gemm_multiply_multiply|moe)")
                message(DEBUG "Skipping ${source} example for current target")
                list(REMOVE_ITEM FILE_NAME "${source}")
            endif()
        endif()
    endforeach()
    #only continue if there are some source files left on the list
    set(source_name_list "")
    foreach(source IN LISTS FILE_NAME)
        get_filename_component(source_name ${source} NAME)
        list(APPEND source_name_list ${source_name})
    endforeach()
    if(FILE_NAME)
        if(source_name_list MATCHES "_xdl" AND NOT source_name_list MATCHES "_pk_i4")
            list(REMOVE_ITEM EX_TARGETS gfx900 gfx906 gfx906:xnack- gfx1030 gfx10-3-generic)
        elseif(source_name_list MATCHES "_wmma")
            list(REMOVE_ITEM EX_TARGETS gfx900 gfx906 gfx906:xnack- gfx908:xnack+ gfx908:xnack- gfx90a:xnack+ gfx90a:xnack- gfx908 gfx90a gfx942 gfx1030 gfx950)
        elseif(source_name_list MATCHES "_mx") #only build mx example for gfx950
            list(REMOVE_ITEM EX_TARGETS gfx900 gfx906 gfx906:xnack- gfx908:xnack+ gfx908:xnack- gfx90a:xnack+ gfx90a:xnack- gfx908 gfx90a gfx942 gfx1030 gfx1100 gfx1101 gfx1102 gfx1103 gfx1150 gfx1151 gfx1152 gfx1153 gfx1200 gfx1201 gfx10-3-generic gfx11-generic gfx12-generic)
        elseif(source_name_list MATCHES "_pk_i4") #only build these examples for gfx942 gfx950 and rdna3/4
            message(DEBUG "trimming targets for ${FILE_NAME}")
            list(REMOVE_ITEM EX_TARGETS gfx900 gfx906 gfx906:xnack- gfx908:xnack+ gfx908:xnack- gfx90a:xnack+ gfx90a:xnack- gfx908 gfx90a gfx1030 gfx10-3-generic)
        endif()
        set_source_files_properties(${FILE_NAME} PROPERTIES LANGUAGE HIP)
        add_executable(${EXAMPLE_NAME} ${FILE_NAME})
        target_link_libraries(${EXAMPLE_NAME} PRIVATE utility)
        target_link_libraries(${EXAMPLE_NAME} PRIVATE getopt::getopt)
        add_test(NAME ${EXAMPLE_NAME} COMMAND $<TARGET_FILE:${EXAMPLE_NAME}> ${ARGN})
        set_property(TARGET ${EXAMPLE_NAME} PROPERTY HIP_ARCHITECTURES ${EX_TARGETS})
        add_dependencies(examples ${EXAMPLE_NAME})
        add_dependencies(check ${EXAMPLE_NAME})
        rocm_install(TARGETS ${EXAMPLE_NAME} COMPONENT examples)
        set(result 0)
    endif()
    message(DEBUG "add_example returns ${result}")
    if(result EQUAL 0 AND NOT "${EXAMPLE_NAME}" IN_LIST REGRESSION_EXAMPLES)
        set_tests_properties(${EXAMPLE_NAME} PROPERTIES LABELS "SMOKE_TEST")
        add_dependencies(smoke ${EXAMPLE_NAME})
    elseif(result EQUAL 0 AND "${EXAMPLE_NAME}" IN_LIST REGRESSION_EXAMPLES)
        set_tests_properties(${EXAMPLE_NAME} PROPERTIES LABELS "REGRESSION_TEST")
        add_dependencies(regression ${EXAMPLE_NAME})
    endif()
    set(result ${result} PARENT_SCOPE)
endfunction(add_example_executable EXAMPLE_NAME)

function(add_example_dependencies EXAMPLE_NAME FILE_NAME)
    if(result EQUAL 0)
        add_dependencies(${EXAMPLE_NAME} ${FILE_NAME})
    endif()
endfunction(add_example_dependencies EXAMPLE_NAME)

function(add_example_executable_no_testing EXAMPLE_NAME FILE_NAME)
    message(DEBUG "adding example ${EXAMPLE_NAME}")
    set(result 1)
    if(DEFINED DTYPES)
        foreach(source IN LISTS FILE_NAME)
            get_filename_component(source_name ${source} NAME)
            set(test 0)
            if((source_name MATCHES "_fp16" OR source_name MATCHES "_f16") AND NOT "fp16" IN_LIST DTYPES)
                set(test 1)
            endif()
            if((source_name MATCHES "_fp32" OR source_name MATCHES "_f32") AND NOT "fp32" IN_LIST DTYPES)
                set(test 1)
            endif()
            if((source_name MATCHES "_fp64" OR source_name MATCHES "_f64") AND NOT "fp64" IN_LIST DTYPES)
                set(test 1)
            endif()
            if((source_name MATCHES "_fp8" OR source_name MATCHES "_f8") AND NOT "fp8" IN_LIST DTYPES)
                set(test 1)
            endif()
            if((source_name MATCHES "_bf8" OR source_name MATCHES "_bf8") AND NOT "bf8" IN_LIST DTYPES)
                set(test 1)
            endif()
            if((source_name MATCHES "_bf16" OR source_name MATCHES "_b16") AND NOT "bf16" IN_LIST DTYPES)
                set(test 1)
            endif()
            if((source_name MATCHES "_int8" OR source_name MATCHES "_i8") AND NOT "int8" IN_LIST DTYPES)
                set(test 1)
            endif()
            if(test EQUAL 1)
                message(DEBUG "removing example ${source} ")
                list(REMOVE_ITEM FILE_NAME "${source}")
            endif()
        endforeach()
    endif()

    set(EX_TARGETS ${SUPPORTED_GPU_TARGETS})

    set(source_name_list "")
    foreach(source IN LISTS FILE_NAME)
        get_filename_component(source_name ${source} NAME)
        #Do not build any DL examples if DL_KERNELS not set
        if(NOT DEFINED DL_KERNELS AND source_name MATCHES "_dl")
            message(DEBUG "removing dl example ${source} ")
            list(REMOVE_ITEM FILE_NAME "${source}")
        endif()
        #Do not build any XDL examples if gfx9 targets are not on the list
        if(NOT EX_TARGETS MATCHES "gfx9" AND NOT EX_TARGETS MATCHES "gfx11" AND NOT EX_TARGETS MATCHES "gfx12" AND source_name MATCHES "_xdl")
            message(DEBUG "removing xdl example ${source} ")
            list(REMOVE_ITEM FILE_NAME "${source}")
        endif()
        #Do not build any WMMA examples if gfx11 targets are not on the list
        if(NOT EX_TARGETS MATCHES "gfx11" AND NOT EX_TARGETS MATCHES "gfx12" AND source_name MATCHES "_wmma")
            message(DEBUG "removing wmma example ${source} ")
            list(REMOVE_ITEM FILE_NAME "${source}")
        endif()
        list(APPEND source_name_list ${source_name})
    endforeach()
    #only continue if there are some source files left on the list
    if(FILE_NAME)
        if(source_name_list MATCHES "_xdl")
            list(REMOVE_ITEM EX_TARGETS gfx900 gfx906 gfx906:xnack- gfx1030 gfx10-3-generic)
        elseif(source_name_list MATCHES "_wmma")
            list(REMOVE_ITEM EX_TARGETS gfx900 gfx906 gfx906:xnack- gfx908:xnack+ gfx908:xnack- gfx90a:xnack+ gfx90a:xnack- gfx908 gfx90a gfx942 gfx1030 gfx950)
        endif()
        set_source_files_properties(${FILE_NAME} PROPERTIES LANGUAGE HIP)
        add_executable(${EXAMPLE_NAME} ${FILE_NAME})
        target_link_libraries(${EXAMPLE_NAME} PRIVATE utility)
        target_link_libraries(${EXAMPLE_NAME} PRIVATE getopt::getopt)
        add_dependencies(examples ${EXAMPLE_NAME})
        set_property(TARGET ${EXAMPLE_NAME} PROPERTY HIP_ARCHITECTURES ${EX_TARGETS})
        rocm_install(TARGETS ${EXAMPLE_NAME} COMPONENT examples)
        set(result 0)
    endif()

    message(DEBUG "add_example returns ${result}")
    set(result ${result} PARENT_SCOPE)

endfunction(add_example_executable_no_testing EXAMPLE_NAME)

function(example_compile_options EXAMPLE_NAME)
    if(TARGET ${EXAMPLE_NAME})
        target_compile_options(${EXAMPLE_NAME} ${ARGN})
    endif()
endfunction(example_compile_options)

# add all example subdir
file(GLOB dir_list LIST_DIRECTORIES true *)
FOREACH(subdir ${dir_list})
    if(IS_DIRECTORY "${subdir}" AND EXISTS "${subdir}/CMakeLists.txt")
        add_subdirectory(${subdir})
    ENDIF()
ENDFOREACH()