mirror of
https://github.com/ROCm/composable_kernel.git
synced 2026-07-12 10:08:01 +00:00
60b276647b
[CK Tile] Rule-based configuration generation in CK Dispatcher codegen (#8157) MIME-Version: 1.0 Content-Type: text/plain; charset=UTF-8 Content-Transfer-Encoding: 8bit ## Motivation The CK Tile Dispatcher code generation for CK Tile Profiler relies on flat JSON files to list the generated configurations. This approach has the following problems - The JSON files are verbose - The JSON files get easily out of sync with the CK Builder .config files from which they were generated from. - The JSON file based configuration make it hard to list explicitly the rules that govern the instance generation. ## Technical Details Replaced the JSON files with a rule based configuration. To preserve the existing functionality, the `profiler` and the `tests` instance sets are generated directly from the CK Builder config files. The JSON config files are removed from source control, and the "on-the-fly" generation guarantees that the Dispatcher codegen uses up to date configurations. This is PR introduces six different rule sets for the CK Tile Dispatcher code generation 1. `profiler`: matches with the old JSON set of profiler configurations. 2. `tests`: matches with the old JSON set of tests configurations. 3. `full`: full configuration set created from a rule-based config selection 4. `full-tests`: a subset of `full` for generating configurations for convolution integration tests. 5. `tiny`: a subset of `full-tests` to produce the minimal set of configurations to test the Dispatcher codegen. 6. `default`: the default rules, which corresponds to the existing heuristic rules for configuration selection. This ensures that ML based kernel selection doesn't get broken. The main use of the `full` rule set is to define a reasonable solution space for the possible implicit GEMM configurations. We start from the configurations that allowed by the device architecture. The `full` rule set defines the relevant tile sizes for each convolution direction. From the tile size we have a curated mapping to the number of waves over the different GEMM axes, i.e., we describe how many waves each GEMM dimensions corresponds to. The GEMM-K wave tile dimension can be computed from the other parameters and does not need to be listed explicitly. An orthogonal axis to the tiling strategy is the vectorization strategy. This mainly defined by the data type and hardware as in general, we want to use the maximum possible load widths. The maximum sizes for each convolution direction variant are defined by the implicit GEMM matrix dimensions. For cases where have a low number of channels per convolution group, we need smaller vector load sizes. These are captured by the `VecStrategy` enumeration in the codegen rules. The problem with the rule based configuration selection is that we "over generate" configurations. The old JSON configurations compose approximately 25% of all configuration that the `full` rule set creates. The additional configurations are valid, but they many not provide any performance benefits. Hence, we keep the `profiler` and `tests` rule set for now to avoid building an excessive amount configurations by default. The `full` rule set can be taken into use by specifying CMake configuration flag `-D DISPATCHER_RULE_SET=full`. By default, the `tests` rule set is used, i.e., we don't change the existing bahaviour. ## Test Plan Added a new stage in the CI/CD pipeline that ensures the Dispatcher codegen rules are up to date. Otherwise the functionality is covered by the existing CI/CD tests. There are no functional changes to the convolution kernels. Only how the different instances are generated. ## Test Result If the CK Tile conv instances build without errors, the Dispatcher codegen is generating valid code. If all tests in CI/CD pipeline are passing, the Dispatcher codegen generates valid instances. ## Submission Checklist - [x] Look over the contributing guidelines at https://github.com/ROCm/ROCm/blob/develop/CONTRIBUTING.md#pull-requests.
143 lines
5.6 KiB
CMake
143 lines
5.6 KiB
CMake
# Copyright (c) Advanced Micro Devices, Inc., or its affiliates.
|
|
# SPDX-License-Identifier: MIT
|
|
#
|
|
# Dispatcher instance OBJECT libraries for CK Tile grouped convolution.
|
|
#
|
|
# Defines ck_add_dispatcher_conv_instances() and creates targets:
|
|
# ck_dispatcher_grouped_conv_fwd
|
|
# ck_dispatcher_grouped_conv_bwd_weight
|
|
# ck_dispatcher_grouped_conv_bwd_data
|
|
#
|
|
# Each target is an OBJECT library compiled from codegen-generated kernel sources.
|
|
# Include via add_subdirectory() from a parent that has already called find_package(Python3).
|
|
|
|
# ---- Configuration (inherits from parent scope) ----
|
|
|
|
set(DISPATCHER_DIR "${PROJECT_SOURCE_DIR}/dispatcher")
|
|
set(DISPATCHER_RULE_SET "tests" CACHE STRING "Dispatcher rule set: profiler, tests, full, full-tests, tiny, or default")
|
|
|
|
# Extract first GPU target for codegen
|
|
string(REPLACE ";" " " _GPU_TARGETS_SPACE "${GPU_TARGETS}")
|
|
string(REPLACE " " ";" _GPU_TARGETS_LIST "${_GPU_TARGETS_SPACE}")
|
|
list(GET _GPU_TARGETS_LIST 0 _GPU_TARGET)
|
|
|
|
# ---- Variant-to-path mapping tables ----
|
|
|
|
set(_DISP_GEN_SCRIPT "generate_profiler_kernels.py")
|
|
|
|
set(_DISP_HEADER_PREFIX_fwd "grouped_conv_fwd_")
|
|
set(_DISP_HEADER_PREFIX_bwd_weight "grouped_conv_bwd_weight_")
|
|
set(_DISP_HEADER_PREFIX_bwd_data "grouped_conv_bwd_data_")
|
|
|
|
|
|
# =============================================================================
|
|
# ck_add_dispatcher_conv_instances(<variant>)
|
|
#
|
|
# Creates an OBJECT library target: ck_dispatcher_grouped_conv_<variant>
|
|
# and a convenience target: dispatcher_<variant>_lib
|
|
#
|
|
# <variant> must be one of: fwd, bwd_weight, bwd_data
|
|
# =============================================================================
|
|
function(ck_add_dispatcher_conv_instances VARIANT)
|
|
# Look up variant-specific paths
|
|
set(HEADER_PREFIX "${_DISP_HEADER_PREFIX_${VARIANT}}")
|
|
|
|
if(NOT HEADER_PREFIX)
|
|
message(FATAL_ERROR "Unknown dispatcher variant: ${VARIANT}")
|
|
endif()
|
|
|
|
set(SCRIPT_PATH "${DISPATCHER_DIR}/scripts/${_DISP_GEN_SCRIPT}")
|
|
set(KERNEL_DIR "${CMAKE_CURRENT_BINARY_DIR}/dispatcher_${VARIANT}_kernels")
|
|
set(TARGET_NAME "ck_dispatcher_grouped_conv_${VARIANT}")
|
|
|
|
# --- Step 1: Run Python codegen at configure time ---
|
|
# Always regenerate: DISPATCHER_RULE_SET is a CACHE variable, so changing it
|
|
# triggers a full reconfigure. Wipe the kernel dir first to remove stale files.
|
|
file(REMOVE_RECURSE ${KERNEL_DIR})
|
|
file(MAKE_DIRECTORY ${KERNEL_DIR})
|
|
execute_process(
|
|
COMMAND ${Python3_EXECUTABLE} ${SCRIPT_PATH}
|
|
--variant ${VARIANT}
|
|
--output-dir ${KERNEL_DIR}
|
|
--arch ${_GPU_TARGET}
|
|
--rule-set ${DISPATCHER_RULE_SET}
|
|
RESULT_VARIABLE ret
|
|
OUTPUT_VARIABLE output
|
|
ERROR_VARIABLE error
|
|
WORKING_DIRECTORY ${DISPATCHER_DIR}/codegen
|
|
)
|
|
if(NOT ret EQUAL 0)
|
|
message(FATAL_ERROR "Dispatcher ${VARIANT} kernel generation failed.\nReturn: ${ret}\nOutput: ${output}\nError: ${error}")
|
|
endif()
|
|
message(STATUS "Dispatcher ${VARIANT} kernels generated (rule set: ${DISPATCHER_RULE_SET}): ${output}")
|
|
|
|
# --- Step 2: Create .cpp wrappers for each generated kernel header ---
|
|
file(GLOB _KERNEL_HEADERS "${KERNEL_DIR}/${HEADER_PREFIX}*.hpp")
|
|
set(_KERNEL_SOURCES "")
|
|
foreach(HEADER ${_KERNEL_HEADERS})
|
|
get_filename_component(STEM ${HEADER} NAME_WE)
|
|
set(WRAPPER_CPP "${KERNEL_DIR}/${STEM}.cpp")
|
|
if(NOT EXISTS ${WRAPPER_CPP})
|
|
file(WRITE ${WRAPPER_CPP} "// Auto-generated wrapper\n#include \"${STEM}.hpp\"\n")
|
|
endif()
|
|
list(APPEND _KERNEL_SOURCES ${WRAPPER_CPP})
|
|
endforeach()
|
|
|
|
if(NOT _KERNEL_SOURCES)
|
|
message(WARNING "Dispatcher ${VARIANT}: no kernel sources generated, skipping target creation")
|
|
return()
|
|
endif()
|
|
|
|
# --- Step 3: Add chunked registration .cpp files ---
|
|
file(GLOB _REG_CPPS "${KERNEL_DIR}/register_*.cpp")
|
|
foreach(REG_CPP ${_REG_CPPS})
|
|
list(APPEND _KERNEL_SOURCES "${REG_CPP}")
|
|
set_source_files_properties("${REG_CPP}" PROPERTIES
|
|
COMPILE_OPTIONS "-Wno-ctad-maybe-unsupported;-Wno-old-style-cast"
|
|
)
|
|
endforeach()
|
|
|
|
# --- Step 4: Create OBJECT library ---
|
|
add_library(${TARGET_NAME} OBJECT ${_KERNEL_SOURCES})
|
|
target_include_directories(${TARGET_NAME} PRIVATE
|
|
${PROJECT_SOURCE_DIR}/include
|
|
${PROJECT_SOURCE_DIR}/dispatcher/include
|
|
${KERNEL_DIR}
|
|
)
|
|
target_compile_options(${TARGET_NAME} PRIVATE
|
|
-DCK_TILE_FLOAT_TO_BFLOAT16_DEFAULT=0
|
|
-DCK_TILE_EXPERIMENTAL_USE_BUFFER_LOAD_OOB_CHECK_OFFSET_TRICK=1
|
|
-Wno-undefined-func-template
|
|
-Wno-float-equal
|
|
-Wno-header-hygiene
|
|
-Wno-unused-parameter
|
|
-Wno-missing-variable-declarations
|
|
# New clang -Weverything suggestion firing on builder-pattern setters that
|
|
# return *this in the shared dispatcher headers; not a real defect.
|
|
-Wno-lifetime-safety-intra-tu-suggestions
|
|
)
|
|
if(NOT WIN32 AND ${hip_VERSION_FLAT} GREATER 600241132)
|
|
target_compile_options(${TARGET_NAME} PRIVATE --offload-compress)
|
|
endif()
|
|
set_target_properties(${TARGET_NAME} PROPERTIES POSITION_INDEPENDENT_CODE ON)
|
|
|
|
# Progress monitoring
|
|
list(LENGTH _KERNEL_SOURCES _TOTAL_COUNT)
|
|
math(EXPR _KERNEL_COUNT "${_TOTAL_COUNT} - 1")
|
|
message(STATUS "Dispatcher ${VARIANT}: ${_TOTAL_COUNT} compilation units (${_KERNEL_COUNT} kernels + registration)")
|
|
|
|
# Convenience ninja target: ninja dispatcher_<variant>_lib
|
|
add_custom_target(dispatcher_${VARIANT}_lib
|
|
DEPENDS ${TARGET_NAME}
|
|
COMMENT "All ${_TOTAL_COUNT} dispatcher ${VARIANT} instances compiled."
|
|
)
|
|
endfunction()
|
|
|
|
|
|
# =============================================================================
|
|
# Create all three dispatcher instance libraries
|
|
# =============================================================================
|
|
ck_add_dispatcher_conv_instances(fwd)
|
|
ck_add_dispatcher_conv_instances(bwd_weight)
|
|
ck_add_dispatcher_conv_instances(bwd_data)
|