mirror of
https://github.com/ROCm/composable_kernel.git
synced 2026-05-27 08:25:46 +00:00
d107f3c3a5
* Adding 16x16x128 support for gfx950 * Support for fp8 and bf8 * fix input arguments for MFMA scale instruction * clang-formatted * Fixes for lwpck-3145 (#2138) * Fix lds tile & cmake dep & default epilogue * Fallback BTypeToUse to ADataType in WOQ cases * reverting instance json file * reverting instance json file --------- Co-authored-by: Yi DING <yi.ding@amd.com>
51 lines
2.0 KiB
CMake
51 lines
2.0 KiB
CMake
|
|
|
|
# generate a list of kernels, but not actually emit files at config stage
|
|
execute_process(
|
|
COMMAND ${Python3_EXECUTABLE} ${CMAKE_CURRENT_LIST_DIR}/gemm_instance_builder.py
|
|
--working_path ${CMAKE_CURRENT_BINARY_DIR}
|
|
--json ${CMAKE_CURRENT_LIST_DIR}/configs/instance_combination.json
|
|
--list_blobs
|
|
RESULT_VARIABLE ret
|
|
)
|
|
set_property(DIRECTORY APPEND PROPERTY CMAKE_CONFIGURE_DEPENDS
|
|
${CMAKE_CURRENT_LIST_DIR}/gemm_instance_builder.py
|
|
${CMAKE_CURRENT_LIST_DIR}/configs/instance_combination.json
|
|
)
|
|
|
|
if(ret AND NOT ret EQUAL 0)
|
|
message( FATAL_ERROR "Fail to generate kernels via Python. ${ret}")
|
|
endif()
|
|
|
|
file(STRINGS ${CMAKE_CURRENT_BINARY_DIR}/gemm_instance_blobs.txt GEMM_CODEGEN_BLOBS)
|
|
|
|
add_custom_command(
|
|
OUTPUT ${GEMM_CODEGEN_BLOBS}
|
|
COMMAND ${Python3_EXECUTABLE} ${CMAKE_CURRENT_LIST_DIR}/gemm_instance_builder.py
|
|
--working_path ${CMAKE_CURRENT_BINARY_DIR}
|
|
--json ${CMAKE_CURRENT_LIST_DIR}/configs/instance_combination.json
|
|
--gen_blobs
|
|
DEPENDS ${CMAKE_CURRENT_LIST_DIR}/gemm_instance_builder.py
|
|
${CMAKE_CURRENT_BINARY_DIR}/gemm_instance_blobs.txt
|
|
${CMAKE_CURRENT_LIST_DIR}/configs/instance_combination.json
|
|
)
|
|
|
|
set(EXECUTABLE_GEMM_INSTANCE "tile_engine_gemm")
|
|
message("adding example ${EXECUTABLE_GEMM_INSTANCE}")
|
|
|
|
# use build as include directory
|
|
include_directories(${CMAKE_CURRENT_BINARY_DIR})
|
|
add_executable(${EXECUTABLE_GEMM_INSTANCE} EXCLUDE_FROM_ALL gemm_host_api.cpp)
|
|
target_include_directories(${EXECUTABLE_GEMM_INSTANCE} PRIVATE ${CMAKE_CURRENT_LIST_DIR})
|
|
target_sources(${EXECUTABLE_GEMM_INSTANCE} PRIVATE ${GEMM_CODEGEN_BLOBS})
|
|
|
|
set(EXECUTABLE_GEMM_INSTANCE_COMPILE_OPTIONS)
|
|
|
|
list(APPEND EXECUTABLE_GEMM_INSTANCE_COMPILE_OPTIONS
|
|
-Wno-undefined-func-template
|
|
-Wno-float-equal
|
|
--offload-compress)
|
|
|
|
target_compile_options(${EXECUTABLE_GEMM_INSTANCE} PRIVATE ${EXECUTABLE_GEMM_INSTANCE_COMPILE_OPTIONS})
|
|
|
|
set_property(GLOBAL PROPERTY RULE_MESSAGES OFF) |