amd/blis
1
0
Fork 0
mirror of https://github.com/amd/blis.git synced 2026-05-05 15:01:13 +00:00
Code Issues Packages Projects Releases Wiki Activity
Files
8f399c89403d5824ba767df1426706cf2d19d0a7
blis/kernels/armv7a/3/bli_cgemm_armv7a_asm_2x2.S
Field G. Van Zee 453deb2906 Implemented runtime kernel management. 
Details:
- Reworked the build system around a configuration registry file, named
  config_registry', that identifies valid configuration targets, their
  constituent sub-configurations, and the kernel sets that are needed by
  those sub-configurations. The build system now facilitates the building
  of a single library that can contains kernels and cache/register
  blocksizes for multiple configurations (microarchitectures). Reference
  kernels are also built on a per-configuration basis.
- Updated the Makefile to use new variables set by configure via the
  config.mk.in template, such as CONFIG_LIST, KERNEL_LIST, and KCONFIG_MAP,
  in determining which sub-configurations (CONFIG_LIST) and kernel sets
  (KERNEL_LIST) are included in the library, and which make_defs.mk files'
  CFLAGS (KCONFIG_MAP) are used when compiling kernels.
- Reorganized 'kernels' directory into a "flat" structure. Renamed kernel
  functions into a standard format that includes the kernel set name
  (e.g. 'haswell'). Created a "bli_kernels_<kernelset>.h" file in each
  kernels sub-directory. These files exist to provide prototypes for the
  kernels present in those directories.
- Reorganized reference kernels into a top-level 'ref_kernels' directory.
  This directory includes a new source file, bli_cntx_ref.c (compiled on
  a per-configuration basis), that defines the code needed to initialize
  a reference context and a context for induced methods for the
  microarchitecture in question.
- Rewrote make_defs.mk files in each configuration so that the compiler
  variables (e.g. CFLAGS) are "stored" (renamed) on a per-configuration
  basis.
- Modified bli_config.h.in template so that bli_config.h is generated with
  #defines for the config (family) name, the sub-configurations that are
  associated with the family, and the kernel sets needed by those
  sub-configurations.
- Deprecated all kernel-related information in bli_kernel.h and transferred
  what remains to new header files named "bli_arch_<configname>.h", which
  are conditionally #included from a new header bli_arch.h. These files
  are still needed to set library-wide parameters such as custom
  malloc()/free() functions or SIMD alignment values.
- Added bli_cntx_init_<configname>.c files to each configuration directory.
  The files contain a function, named the same as the file, that initializes
  a "native" context for a particular configuration (microarchitecture). The
  idea is that optimized kernels, if available, will be initialized into
  these contexts. Other fields will retain pointers to reference functions,
  which will be compiled on a per-configuration basis. These bli_cntx_init_*()
  functions will be called during the initialization of the global kernel
  structure. They are thought of as initializing for "native" execution, but
  they also form the basis for contexts that use induced methods. These
  functions are prototyped, along with their _ref() and _ind() brethren, by
  prototype-generating macros in bli_arch.h.
- Added a new typedef enum in bli_type_defs.h to define an arch_t, which
  identifies the various sub-configurations.
- Redesigned the global kernel structure (gks) around a 2D array of cntx_t
  structures (pointers to cntx_t, actually). The first dimension is indexed
  over arch_t and the inner dimension is the ind_t (induced method) for
  each microarchitecture. When a microarchitecture (configuration) is
  "registered" at init-time, the inner array for that configuration in the
  2D array is initialized (and allocated, if it hasn't been already). The
  cntx_t slot for BLIS_NAT is initialized immediately and those for other
  induced method types are initialized and cached on-demand, as needed. At
  cntx_t registration, we also store function pointers to cntx_init functions
  that will initialize (a) "reference" contexts and (b) contexts for use with
  induced methods. We don't cache the full contexts for reference contexts
  since they are rarely needed. The functions that initialize these two kinds
  of contexts are generated automatically for each targeted sub-configuration
  from cpp-templatized code at compile-time. Induced method contexts that
  need "stage" adjustments can still obtain them via functions in
  bli_cntx_ind_stage.c.
- Added new functions and functionality to bli_cntx.c, such as for setting
  the level-1f, level-1v, and packm kernels, and for converting a native
  context into one for executing an induced method.
- Moved the checking of register/cache blocksize consistency from being cpp
  macros in bli_kernel_macro_defs.h to being runtime checks defined in
  bli_check.c and called from bli_gks_register_cntx() at the time that the
  global kernel structure's internal context is initialized for a given
  microarchitecture/configuration.
- Deprecated all of the old per-operation bli_*_cntx.c files and removed
  the previous operation-level cntx_t_init()/_finalize() invocations.
  Instead, we now query the gks for a suitable context, usually via
  bli_gks_query_cntx().
- Deprecated support for the 3m2 and 3m3 induced methods. (They required
  hackery that I was no longer willing to support.)
- Consolidated the 1e and 1r packm kernels for any given register blocksize
  into a single kernel that will branch on the schema and support packing
  to both formats.
- Added the cntx_t* argument to all packm kernel signatures.
- Deprecated the local function pointer array in all bli_packm_cxk*.c files
  and instead obtain the packm kernel from the cntx_t.
- Added bli_calloc_intl(), which serves as the calloc-equivalent to to
  bli_malloc_intl(). Useful when we wish to allocate and initialize to
  zero/NULL.
- Converted existing cpp macro functions defined in bli_blksz.h, bli_func.h,
  bli_cntx.h into static functions.
2017-10-18 13:29:32 -05:00

503 lines
9.7 KiB
ArmAsm
Raw Blame History

#define REALNAME bli_cgemm_armv7a_ker_2x2
#define STACKSIZE 256
#define K r0
#define PTR_ALPHA r1
#define OLD_A r2
#define OLD_B r3
#define PTR_BETA [fp, #0 ]
#define OLD_C [fp, #4 ]
#define OLD_RSC [fp, #8 ]
#define OLD_CSC [fp, #12 ]
#define AUX [fp, #16 ]
/******************************************************
* [fp, #-128] - [fp, #-64] is reserved
* for store and restore of floating point
* register
*******************************************************/
#define L r2
#define AO r5
#define BO r6
#define CO1 r7
#define CO2 r8
#define A_PRE 96
#define B_PRE 96
#define C_PRE 0
/**************************************************************************************
* Macro definitions
**************************************************************************************/
#define FMAC_BR fnmacs
#define FMAC_BI fmacs
#define NN 1
#if defined(NN) || defined(NT) || defined(TN) || defined(TT)
#define FADD_R fsubs
#define FADD_I fadds
#define FMAC_R1 fnmacs
#define FMAC_R2 fnmacs
#define FMAC_I1 fmacs
#define FMAC_I2 fnmacs
#elif defined(CN) || defined(CT)
#define FADD_R fadds
#define FADD_I fsubs
#define FMAC_R1 fmacs
#define FMAC_R2 fmacs
#define FMAC_I1 fnmacs
#define FMAC_I2 fmacs
#elif defined(NC) || defined(TC)
#define FADD_R fadds
#define FADD_I fsubs
#define FMAC_R1 fmacs
#define FMAC_R2 fnmacs
#define FMAC_I1 fmacs
#define FMAC_I2 fmacs
#else
#define FADD_R fsubs
#define FADD_I fadds
#define FMAC_R1 fnmacs
#define FMAC_R2 fmacs
#define FMAC_I1 fnmacs
#define FMAC_I2 fnmacs
#endif
.macro INIT2x2
vsub.f32 s16 , s16 , s16
vmov.f32 s17, s16
vmov.f32 s18, s16
vmov.f32 s19, s16
vmov.f32 s20, s16
vmov.f32 s21, s16
vmov.f32 s22, s16
vmov.f32 s23, s16
vmov.f32 s24, s16
vmov.f32 s25, s16
vmov.f32 s26, s16
vmov.f32 s27, s16
vmov.f32 s28, s16
vmov.f32 s29, s16
vmov.f32 s30, s16
vmov.f32 s31, s16
.endm
.macro KERNEL2x2_I
pld [ AO , #A_PRE ]
pld [ BO , #B_PRE ]
flds s0 , [ AO ]
flds s1 , [ AO, #4 ]
flds s8 , [ BO ]
flds s9 , [ BO, #4 ]
fmuls s16 , s0, s8
flds s2 , [ AO, #8 ]
fmuls s24 , s1, s9
flds s3 , [ AO, #12 ]
fmuls s17 , s0, s9
flds s10, [ BO, #8 ]
fmuls s25 , s1, s8
flds s11, [ BO, #12 ]
fmuls s18 , s2, s8
add BO , BO, #16
fmuls s26 , s3, s9
add AO , AO, #16
fmuls s19 , s2, s9
pld [ BO , #B_PRE ]
fmuls s27 , s3, s8
pld [ AO , #A_PRE ]
fmuls s20 , s0, s10
flds s4 , [ AO, #0 ]
fmuls s28 , s1, s11
flds s5 , [ AO, #4 ]
fmuls s21 , s0, s11
flds s12, [ BO ]
fmuls s29 , s1, s10
flds s13, [ BO, #4 ]
fmuls s22 , s2, s10
flds s6 , [ AO, #8 ]
fmuls s30 , s3, s11
flds s7 , [ AO, #12 ]
fmuls s23 , s2, s11
flds s14, [ BO, #8 ]
fmuls s31 , s3, s10
flds s15, [ BO, #12 ]
add BO , BO, #16
add AO , AO, #16
.endm
.macro KERNEL2x2_M1
pld [ AO , #A_PRE ]
fmacs s16 , s0, s8
pld [ BO , #B_PRE ]
fmacs s24 , s1, s9
flds s4 , [ AO, #0 ]
fmacs s17 , s0, s9
flds s5 , [ AO, #4 ]
fmacs s25 , s1, s8
flds s12, [ BO ]
fmacs s18 , s2, s8
flds s13, [ BO, #4 ]
fmacs s26 , s3, s9
flds s6 , [ AO, #8 ]
fmacs s19 , s2, s9
flds s7 , [ AO, #12 ]
fmacs s27 , s3, s8
fmacs s20 , s0, s10
flds s14, [ BO, #8 ]
fmacs s28 , s1, s11
fmacs s21 , s0, s11
flds s15, [ BO, #12 ]
fmacs s29 , s1, s10
fmacs s22 , s2, s10
add BO , BO, #16
fmacs s30 , s3, s11
fmacs s23 , s2, s11
add AO , AO, #16
fmacs s31 , s3, s10
.endm
.macro KERNEL2x2_M2
fmacs s16 , s4, s12
fmacs s24 , s5, s13
flds s0 , [ AO, #0 ]
fmacs s17 , s4, s13
flds s1 , [ AO, #4 ]
fmacs s25 , s5, s12
fmacs s18 , s6, s12
flds s8 , [ BO ]
fmacs s26 , s7, s13
flds s9 , [ BO, #4 ]
fmacs s19 , s6, s13
fmacs s27 , s7, s12
flds s2 , [ AO, #8 ]
fmacs s20 , s4, s14
flds s3 , [ AO, #12 ]
fmacs s28 , s5, s15
fmacs s21 , s4, s15
flds s10, [ BO, #8 ]
fmacs s29 , s5, s14
flds s11, [ BO, #12 ]
fmacs s22 , s6, s14
fmacs s30 , s7, s15
add BO , BO, #16
fmacs s23 , s6, s15
add AO , AO, #16
fmacs s31 , s7, s14
.endm
.macro KERNEL2x2_E
fmacs s16 , s4, s12
fmacs s24 , s5, s13
fmacs s17 , s4, s13
fmacs s25 , s5, s12
fmacs s18 , s6, s12
fmacs s26 , s7, s13
fmacs s19 , s6, s13
fmacs s27 , s7, s12
fmacs s20 , s4, s14
fmacs s28 , s5, s15
fmacs s21 , s4, s15
fmacs s29 , s5, s14
fmacs s22 , s6, s14
fmacs s30 , s7, s15
fmacs s23 , s6, s15
fmacs s31 , s7, s14
.endm
.macro KERNEL2x2_SUB
flds s0 , [ AO ]
flds s1 , [ AO, #4 ]
flds s8 , [ BO ]
flds s9 , [ BO, #4 ]
fmacs s16 , s0, s8
flds s2 , [ AO, #8 ]
fmacs s24 , s1, s9
flds s3 , [ AO, #12 ]
fmacs s17 , s0, s9
flds s10, [ BO, #8 ]
fmacs s25 , s1, s8
flds s11, [ BO, #12 ]
fmacs s18 , s2, s8
fmacs s26 , s3, s9
fmacs s19 , s2, s9
fmacs s27 , s3, s8
fmacs s20 , s0, s10
fmacs s28 , s1, s11
fmacs s21 , s0, s11
fmacs s29 , s1, s10
fmacs s22 , s2, s10
add BO , BO, #16
fmacs s30 , s3, s11
fmacs s23 , s2, s11
add AO , AO, #16
fmacs s31 , s3, s10
.endm
.macro SAVE2x2
ldr r3, OLD_RSC // Row stride size
lsl r3, r3, #3 // multiply with size of complex float
flds s0, [ PTR_ALPHA ] // load real part of alpha
flds s1, [ PTR_ALPHA, #4 ] // load imag part of alpha
ldr r4, PTR_BETA
flds s2, [ r4 ] // load real part of beta
flds s3, [ r4, #4 ] // load imag part of beta
// Add/Sub the real and the imag parts
FADD_R s16, s24 , s16
FADD_I s17, s25 , s17
FADD_R s18, s26 , s18
FADD_I s19, s27 , s19
FADD_R s20, s28 , s20
FADD_I s21, s29 , s21
FADD_R s22, s30 , s22
FADD_I s23, s31 , s23
mov r4, CO1 // save pointer
fldmias CO1, { s4 - s5 } // read real and imag part from C
add CO1, CO1, r3
mov r2, CO2 // save pointer
fldmias CO2, { s8 - s9 } // read real and imag part from C
add CO2, CO2, r3
fmuls s24, s4, s2 // multiply Beta-real with C-real
fmuls s25, s5, s2 // multiply Beta-real with C-imag
fmuls s28, s8, s2 // multiply Beta-real with C-real
fmuls s29, s9, s2 // multiply Beta-real with C-imag
FMAC_BR s24, s3, s5 // multiply beta-imag with C-imag and add
FMAC_BI s25, s3, s4 // multiply beta-imag with C-real and add
FMAC_BR s28, s3, s9 // multiply beta-imag with C-imag and add
FMAC_BI s29, s3, s8 // multiply beta-imag with C-real and add
FMAC_R1 s24 , s0 , s16
FMAC_I1 s25 , s0 , s17
FMAC_R2 s24 , s1 , s17
FMAC_I2 s25 , s1 , s16
FMAC_R1 s28 , s0 , s20
FMAC_I1 s29 , s0 , s21
FMAC_R2 s28 , s1 , s21
FMAC_I2 s29 , s1 , s20
fldmias CO1, { s4 - s5 } // read real and imag part from C
fldmias CO2, { s8 - s9 } // read real and imag part from C
fmuls s26, s4, s2 // multiply Beta-real with C-real
fmuls s27, s5, s2 // multiply Beta-real with C-imag
fmuls s30, s8, s2 // multiply Beta-real with C-real
fmuls s31, s9, s2 // multiply Beta-real with C-imag
FMAC_BR s26, s3, s5 // multiply beta-imag with C-imag and add
FMAC_BI s27, s3, s4 // multiply beta-imag with C-real and add
FMAC_BR s30, s3, s9 // multiply beta-imag with C-imag and add
FMAC_BI s31, s3, s8 // multiply beta-imag with C-real and add
FMAC_R1 s26 , s0 , s18
FMAC_I1 s27 , s0 , s19
FMAC_R2 s26 , s1 , s19
FMAC_I2 s27 , s1 , s18
FMAC_R1 s30, s0 , s22
FMAC_I1 s31, s0 , s23
FMAC_R2 s30, s1 , s23
FMAC_I2 s31, s1 , s22
mov CO1, r4 // restore pointer
mov CO2, r2 // restore pointer
fstmias CO1, { s24 - s25 }
fstmias CO2, { s28 - s29 }
add CO1, CO1, r3
add CO2, CO2, r3
fstmias CO1, { s26 - s27 }
fstmias CO2, { s30 - s31 }
.endm
/**************************************************************************************
* End of macro definitions
**************************************************************************************/
.arm
.global REALNAME
.func REALNAME
REALNAME:
push {r4 - r9, fp} // save register
add fp, sp, #28 // add number of saved register multiplied by size of int
sub sp, sp, #STACKSIZE // reserve stack
mov AO, OLD_A // pointer matrix A
mov BO, OLD_B // pointer matrix B
sub r3, fp, #128
vstm r3, { s8 - s31} // store floating point registers
ldr r2, OLD_C // pointer matrix C
ldr r3, OLD_CSC // Col stride size of C
lsl r3, r3, #3 // multiply with size of complex float
mov CO1, r2 // first line of C
add CO2, CO1, r3 // second line of C
pld [ CO1, #C_PRE ] // prefetch the lines of C
pld [ CO2, #C_PRE ] // prefetch the lines of C
cgemm_kernel_L2_M2_20:
asrs L , K, #3 // L = K / 8
cmp L , #2
blt cgemm_kernel_L2_M2_32
KERNEL2x2_I
KERNEL2x2_M2
KERNEL2x2_M1
KERNEL2x2_M2
KERNEL2x2_M1
KERNEL2x2_M2
KERNEL2x2_M1
KERNEL2x2_M2
subs L, L, #2
ble cgemm_kernel_L2_M2_22a
.align 5
cgemm_kernel_L2_M2_22:
KERNEL2x2_M1
KERNEL2x2_M2
KERNEL2x2_M1
KERNEL2x2_M2
KERNEL2x2_M1
KERNEL2x2_M2
KERNEL2x2_M1
KERNEL2x2_M2
subs L, L, #1
bgt cgemm_kernel_L2_M2_22
cgemm_kernel_L2_M2_22a:
KERNEL2x2_M1
KERNEL2x2_M2
KERNEL2x2_M1
KERNEL2x2_M2
KERNEL2x2_M1
KERNEL2x2_M2
KERNEL2x2_M1
KERNEL2x2_E
b cgemm_kernel_L2_M2_44
cgemm_kernel_L2_M2_32:
tst L, #1
ble cgemm_kernel_L2_M2_40
KERNEL2x2_I
KERNEL2x2_M2
KERNEL2x2_M1
KERNEL2x2_M2
KERNEL2x2_M1
KERNEL2x2_M2
KERNEL2x2_M1
KERNEL2x2_E
b cgemm_kernel_L2_M2_44
cgemm_kernel_L2_M2_40:
INIT2x2
cgemm_kernel_L2_M2_44:
ands L , K, #7 // L = K % 8
ble cgemm_kernel_L2_M2_100
cgemm_kernel_L2_M2_46:
KERNEL2x2_SUB
subs L, L, #1
bne cgemm_kernel_L2_M2_46
cgemm_kernel_L2_M2_100:
SAVE2x2
cgemm_kernel_L999:
sub r3, fp, #128
vldm r3, { s8 - s31} // restore floating point registers
sub sp, fp, #28
pop {r4 - r9, fp}
bx lr
Reference in New Issue View Git Blame Copy Permalink