mirror of
https://github.com/ikawrakow/ik_llama.cpp.git
synced 2026-04-30 11:21:56 +00:00
f6c8b5f2cb
* Update nix flake: sync with upstream, fix for newer nixpkgs - Sync package.nix with upstream: add rocmGpuTargets/useRpc params, fix env optionals→optionalAttrs, remove unused inputs - Rewrite devshells.nix to use mkShell directly instead of passthru - Fix CUDA license check in nixpkgs-instances.nix for list-type licenses - Update flake inputs (nixpkgs, flake-parts) to latest - Update references from ggerganov/llama.cpp to ikawrakow/ik_llama.cpp Co-Authored-By: Claude Opus 4.6 <noreply@anthropic.com> * Apply nix review suggestions from baileylu121 (#1371) - Use legacyPackages instead of import to avoid extra nixpkgs instances - Use inherit (pkgs) stdenv idiom - Remove unnecessary lib.pipe wrapper in devshells.nix - Simplify license normalization with lib.toList in nixpkgs-instances.nix Co-Authored-By: Claude Sonnet 4.6 <noreply@anthropic.com> --------- Co-authored-by: Claude Opus 4.6 <noreply@anthropic.com>
51 lines
1.7 KiB
Nix
51 lines
1.7 KiB
Nix
{ inputs, ... }:
|
|
{
|
|
# The _module.args definitions are passed on to modules as arguments. E.g.
|
|
# the module `{ pkgs ... }: { /* config */ }` implicitly uses
|
|
# `_module.args.pkgs` (defined in this case by flake-parts).
|
|
perSystem =
|
|
{ lib, system, ... }:
|
|
{
|
|
_module.args = {
|
|
# Note: bringing up https://zimbatm.com/notes/1000-instances-of-nixpkgs
|
|
# again, the below creates several nixpkgs instances which the
|
|
# flake-centric CLI will be forced to evaluate e.g. on `nix flake show`.
|
|
#
|
|
# This is currently "slow" and "expensive", on a certain scale.
|
|
# This also isn't "right" in that this hinders dependency injection at
|
|
# the level of flake inputs. This might get removed in the foreseeable
|
|
# future.
|
|
#
|
|
# Note that you can use these expressions without Nix
|
|
# (`pkgs.callPackage ./devops/nix/scope.nix { }` is the entry point).
|
|
|
|
pkgsCuda = import inputs.nixpkgs {
|
|
inherit system;
|
|
# Ensure dependencies use CUDA consistently (e.g. that openmpi, ucc,
|
|
# and ucx are built with CUDA support)
|
|
config.cudaSupport = true;
|
|
config.allowUnfreePredicate =
|
|
p:
|
|
let
|
|
licenses = lib.toList (p.meta.license or []);
|
|
in
|
|
builtins.all
|
|
(
|
|
license:
|
|
license.free
|
|
|| builtins.elem license.shortName [
|
|
"CUDA EULA"
|
|
"cuDNN EULA"
|
|
]
|
|
)
|
|
licenses;
|
|
};
|
|
# Ensure dependencies use ROCm consistently
|
|
pkgsRocm = import inputs.nixpkgs {
|
|
inherit system;
|
|
config.rocmSupport = true;
|
|
};
|
|
};
|
|
};
|
|
}
|