mirror of
https://github.com/pybind/pybind11.git
synced 2026-04-20 06:49:25 +00:00
07d028f218
* First draft a subinterpreter embedding API * Move subinterpreter tests to their own file * Migrate subinterpreter tests to use the new embedded class. * Add a test for moving subinterpreters across threads for destruction And find a better way to make that work. * Code organization * Add a test which shows demostrates how gil_scoped interacts with sub-interpreters * Add documentation for embeded sub-interpreters * Some additional docs work * Add some convenience accessors * Add some docs cross references * Sync some things that were split out into #5665 * Update subinterpreter docs example to not use the CPython api * Fix pip test * style: pre-commit fixes * Fix MSVC warnings I am surprised other compilers allowed this code with a deleted move ctor. * Add some sub-headings to the docs * Oops, make_unique is C++14 so remove it from the tests. * I think this fixes the EndInterpreter issues on all versions. It just has to be ifdef'd because it is slightly broken on 3.12, working well on 3.13, and kind of crashy on 3.14beta. These two verion ifdefs solve all the issues. * Add a note about exceptions. They contain Python object references and acquire the GIL, that means they are a danger with subinterpreters! * style: pre-commit fixes * Add try/catch to docs examples to match the tips * Python 3.12 is very picky about this first PyThreadState Try special casing the destruction on the same thread. * style: pre-commit fixes * Missed a rename in a ifdef block * I think this test is causing problems in 3.12, so try ifdefing it to see if the problems go away. * style: pre-commit fixes * Document the 3.12 constraints with a warning * Apply suggestions from code review Co-authored-by: Copilot <175728472+Copilot@users.noreply.github.com> * ci: add cpptest to the clang-tidy job Signed-off-by: Henry Schreiner <henryschreineriii@gmail.com> * noexcept move operations * Update include/pybind11/subinterpreter.h std::memset Co-authored-by: Aaron Gokaslan <aaronGokaslan@gmail.com> --------- Signed-off-by: Henry Schreiner <henryschreineriii@gmail.com> Co-authored-by: pre-commit-ci[bot] <66853113+pre-commit-ci[bot]@users.noreply.github.com> Co-authored-by: Henry Schreiner <HenrySchreinerIII@gmail.com> Co-authored-by: Copilot <175728472+Copilot@users.noreply.github.com> Co-authored-by: Aaron Gokaslan <aaronGokaslan@gmail.com>
57 lines
2.1 KiB
CMake
57 lines
2.1 KiB
CMake
possibly_uninitialized(PYTHON_MODULE_EXTENSION Python_INTERPRETER_ID)
|
|
|
|
if("${PYTHON_MODULE_EXTENSION}" MATCHES "pypy"
|
|
OR "${Python_INTERPRETER_ID}" STREQUAL "PyPy"
|
|
OR "${PYTHON_MODULE_EXTENSION}" MATCHES "graalpy")
|
|
message(STATUS "Skipping embed test on PyPy or GraalPy")
|
|
add_custom_target(cpptest) # Dummy target on PyPy or GraalPy. Embedding is not supported.
|
|
set(_suppress_unused_variable_warning "${DOWNLOAD_CATCH}")
|
|
return()
|
|
endif()
|
|
|
|
if(TARGET Python::Module AND NOT TARGET Python::Python)
|
|
message(STATUS "Skipping embed test since no embed libs found")
|
|
add_custom_target(cpptest) # Dummy target since embedding is not supported.
|
|
set(_suppress_unused_variable_warning "${DOWNLOAD_CATCH}")
|
|
return()
|
|
endif()
|
|
|
|
find_package(Catch 2.13.10)
|
|
|
|
if(CATCH_FOUND)
|
|
message(STATUS "Building interpreter tests using Catch v${CATCH_VERSION}")
|
|
else()
|
|
message(STATUS "Catch not detected. Interpreter tests will be skipped. Install Catch headers"
|
|
" manually or use `cmake -DDOWNLOAD_CATCH=ON` to fetch them automatically.")
|
|
return()
|
|
endif()
|
|
|
|
find_package(Threads REQUIRED)
|
|
|
|
add_executable(test_embed catch.cpp test_interpreter.cpp test_subinterpreter.cpp)
|
|
pybind11_enable_warnings(test_embed)
|
|
|
|
target_link_libraries(test_embed PRIVATE pybind11::embed Catch2::Catch2 Threads::Threads)
|
|
|
|
if(NOT CMAKE_CURRENT_SOURCE_DIR STREQUAL CMAKE_CURRENT_BINARY_DIR)
|
|
file(COPY test_interpreter.py test_trampoline.py DESTINATION "${CMAKE_CURRENT_BINARY_DIR}")
|
|
endif()
|
|
|
|
add_custom_target(
|
|
cpptest
|
|
COMMAND "$<TARGET_FILE:test_embed>"
|
|
DEPENDS test_embed
|
|
WORKING_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}")
|
|
|
|
pybind11_add_module(external_module THIN_LTO external_module.cpp)
|
|
set_target_properties(external_module PROPERTIES LIBRARY_OUTPUT_DIRECTORY
|
|
"${CMAKE_CURRENT_BINARY_DIR}")
|
|
foreach(config ${CMAKE_CONFIGURATION_TYPES})
|
|
string(TOUPPER ${config} config)
|
|
set_target_properties(external_module PROPERTIES LIBRARY_OUTPUT_DIRECTORY_${config}
|
|
"${CMAKE_CURRENT_BINARY_DIR}")
|
|
endforeach()
|
|
add_dependencies(cpptest external_module)
|
|
|
|
add_dependencies(check cpptest)
|